func(cadd,{[x]+[y]}):

func(csub,{[x]-[y]}):

func(cmul,{<
  elem([x],1)*elem([y],1)-
  elem([x],2)*elem([y],2),
  elem([x],1)*elem([y],2)+
  elem([x],2)*elem([y],1)>}):

func(conj,{
  <elem([x],1),-1*elem([x],2)>}):

func(cmag2,{
   elem([x]*[x],1)+
   elem([x]*[x],2)}):

func(cmag,{
  sqrt(cmag2([x]))}):

func(cdiv,{
  (cmul([x],conj([y])))/
  (cmag2([y]))
}):

func(cpol,{
  <cmag([x]),
  atan2(elem([x],2),elem([x],1))>}):

func(pcart,{
  elem([x],1)*
  <cos(elem([x],2)),
   sin(elem([x],2))>}):

func(cpow,{
  sub({
    let(a,cpol([x])):
    let(rad,elem([a],1)):
    let(ang,elem([a],2)):
    let(pwr,[y]):
    let(rad,[rad]^[pwr]):
    let(ang,[ang]*[pwr]):
    print_pcart(<[rad],[ang]>)})}):

func(cpow2,{sub({
  let(ex,elem([x],1)):
  let(ey,elem([x],2)):
  let(ea,elem([y],1)):
  let(eb,elem([y],2)):
  let(lnz,[ex]*[ex] + [ey]*[ey]):
  print_iff([lnz]=0,{<0,0>},{sub({
    let(lnz,0.5*ln([lnz])):
    let(argz,atan2([ey],[ex])):
    let(mag,eul([ea]*[lnz] - [eb]*[argz])):
    let(ang,[ea]*[argz] + [eb]*[lnz]):
    print_pcart(<[mag],[ang]>)})})})}):

func(clog,{sub({
  let(ex,elem([x],1)):
  let(ey,elem([x],2)):
  let(lnz,[ex]*[ex] + [ey]*[ey]):
  print_iff([lnz]=0,{<0,0>},{sub({
    let(lnz,0.5*ln([lnz])):
    let(argz,atan2([ey],[ex])):
    print_<[lnz],[argz]>})})})}):

let(c+,~cadd~):
let(c-,~csub~):
let(c*,~cmul~):
let(c/,~cdiv~):
let(c^,~cpow~):
let(c2^,~cpow2~):
let(I,<0,1>):

print_`complexnum.txt',: